Cassandra数据库中的frozen关键字

2018-08-12 1203 words 3 minutes

Contents

1. 概述

在本教程中，我们将讨论Apache Cassandra 数据库中的 frozen关键字。首先，我们将展示如何声明冻结集合或用户定义类型 (UDT) 。接下来，我们将讨论使用示例以及它如何影响持久存储的基本操作。

2. Cassandra 数据库配置

让我们使用docker映像创建一个数据库，并使用cqlsh将其连接到数据库。接下来，我们应该创建一个KEYSPACE：

CREATE KEYSPACE mykeyspace WITH replication = {'class':'SimpleStrategy', 'replication_factor' : 1};

在本教程中，我们创建了一个只有一个数据副本的KEYSPACE。现在，让我们将客户端会话连接到KEYSPACE：

USE mykeyspace;

3. 冻结集合类型

**类型为冻结集合（set、map或list）的列只能将其值作为一个整体替换。**换句话说，我们不能像在非冻结集合类型中那样从集合中添加、更新或删除单个元素。因此，frozen关键字可能很有用，例如，当我们想要保护集合免受单值更新时。

此外，由于冻结，我们可以使用冻结的集合作为表中的主键。我们可以使用集合类型（如set、list或map ）来声明集合列。然后我们添加集合的类型。

要声明一个冻结集合，我们必须在集合定义之前添加关键字：

CREATE TABLE mykeyspace.users
(
    id         uuid PRIMARY KEY,
    ip_numbers frozen<set<inet>>,
    addresses  frozen<map<text, tuple<text>>>,
    emails     frozen<list<varchar>>,
);

让我们插入一些数据：

INSERT INTO mykeyspace.users (id, ip_numbers)
VALUES (6ab09bec-e68e-48d9-a5f8-97e6fb4c9b47, {'10.10.11.1', '10.10.10.1', '10.10.12.1'});

重要的是，正如我们上面提到的，冻结的集合只能作为一个整体来替换。这意味着我们不能添加或删除元素。让我们尝试在ip_numbers集合中添加一个新元素：

UPDATE mykeyspace.users
SET ip_numbers = ip_numbers + {'10.10.14.1'}
WHERE id = 6ab09bec-e68e-48d9-a5f8-97e6fb4c9b47;

执行更新后，我们将收到错误：

InvalidRequest: Error from server: code=2200 [Invalid query] message="Invalid operation (ip_numbers = ip_numbers + {'10.10.14.1'}) for frozen collection column ip_numbers"

如果我们想更新集合中的数据，我们需要更新整个集合：

UPDATE mykeyspace.users
SET ip_numbers = {'11.10.11.1', '11.10.10.1', '11.10.12.1'}
WHERE id = 6ab09bec-e68e-48d9-a5f8-97e6fb4c9b47;

3.1. 嵌套集合

有时我们必须在 Cassandra 数据库中使用嵌套集合。只有当我们将它们标记为 freeze 时，嵌套集合才是可能的。这意味着这个集合将是不可变的。我们可以冻结冻结和非冻结集合中的嵌套集合。让我们看一个例子：

CREATE TABLE mykeyspace.users_score
(
    id    uuid PRIMARY KEY,
    score set<frozen<set<int>>>
);

4. 冻结用户自定义类型

用户定义类型 (UDT) 可以将多个数据字段（每个字段都命名和键入）附加到单个列。用于创建用户定义类型的字段可以是任何有效的数据类型，包括集合或其他 UDT。让我们创建我们的 UDT：

CREATE TYPE mykeyspace.address (
    city text,
    street text,
    streetNo int,
    zipcode text
);

让我们看一下冻结的用户定义类型的声明：

CREATE TABLE mykeyspace.building
(
    id      uuid PRIMARY KEY,
    address frozen<address>
);

当我们在用户定义的类型上使用freeze时，Cassandra 将值视为 blob。这个 blob 是通过将我们的 UDT 序列化为单个值来获得的。所以，我们不能更新用户定义类型 value 的一部分。我们必须覆盖整个值。

首先，让我们插入一些数据：

INSERT INTO mykeyspace.building (id, address)
VALUES (6ab09bec-e68e-48d9-a5f8-97e6fb4c9b48,
  {city: 'City', street: 'Street', streetNo: 2,zipcode: '02-212'});

让我们看看当我们尝试只更新一个字段时会发生什么：

UPDATE mykeyspace.building
SET address.city = 'City2'
WHERE id = 6ab09bec-e68e-48d9-a5f8-97e6fb4c9b48;

我们将再次收到错误：

InvalidRequest: Error from server: code=2200 [Invalid query] message="Invalid operation (address.city = 'City2') for frozen UDT column address"

所以，让我们更新整个值：

UPDATE mykeyspace.building
SET address = {city : 'City2', street : 'Street2'}
WHERE id = 6ab09bec-e68e-48d9-a5f8-97e6fb4c9b48;

这一次，地址将被更新。未包含在查询中的字段以null值完成。

5. 元组

与其他组合类型不同，元组总是被冻结的。因此，我们不必用freeze关键字标记元组。因此，不可能只更新元组的某些元素。与冻结集合或 UDT 的情况一样，我们必须覆盖整个值。